home *** CD-ROM | disk | FTP | other *** search
/ FishMarket 1.0 / FishMarket v1.0.iso / fishies / 476-500 / disk_483 / td / td.asm < prev    next >
Assembly Source File  |  1992-05-06  |  14KB  |  546 lines
  1. *    TD V1.0
  2. *    By Preben Nielsen
  3. *
  4. *    Based on 'TrackDisplay' on Fish-disk 399 by Olaf Barthel.
  5. *
  6. *      TD is a program that continuously monitors and displays
  7. *    the current track for each connected floppy disk.
  8. *
  9. *      The size of the window and the use of colors in it depends on
  10. *    the version of the Kickstart/Workbench (1.2/1.3 vs. 2.?).
  11. *
  12. *    NOTE:    There's no need to 'RUN' or 'RUNBACK' this program from the
  13. *        CLI. It is auto-detaching.
  14. *
  15. *HISTORY
  16. *          Made with Hisoft V2.12
  17. * 
  18. *           January: Recieved 'Trackdisplay' on Fish-disk 399.
  19. *                    Nice program Olaf. Thanks.
  20. *
  21. *  V1.0   03-Mar-91: First working version.
  22. *         04-Mar-91: Added auto-detaching code.
  23. *         07-Mar-91: Uses 'PrintIText' instead of 'Move'/'Text'. Because of
  24. *                    this, my version used nearly twice the amount of
  25. *                    processor-time as the original (according to Xoper).
  26. *         15-Mar-91: Now uses 'Move'/'Text'. Code is now larger but faster.
  27. *         19-Apr-91: Made some modifications to make it look better
  28. *                    under WB2.0 (haven't actually tried it yet)
  29.  
  30.     OPT O+
  31.     OPT O1+            ; Tells when a branch could be optimised to short
  32.     OPT i+            ; Tells when '#' is probably missing
  33.  
  34. Prepare        MACRO
  35.         IFC        '\1','Exec_Call'
  36.         movea.l        4.W,A6
  37.         ENDC
  38.         IFC        '\1','Intuition_Call'
  39.         movea.l        IntBase(DB),A6
  40.         ENDC
  41.         IFC        '\1','Gfx_Call'
  42.         movea.l        GfxBase(DB),A6
  43.         ENDC
  44.         IFC        '\1','Dos_Call'
  45.         movea.l        DosBase(DB),A6
  46.         ENDC
  47.         ENDM
  48. CallLib        MACRO
  49.         jsr        _LVO\1(A6)
  50.         ENDM
  51. Call        MACRO
  52.         bsr        \1
  53.         ENDM
  54. Push        MACRO        Push <reg-list | All>
  55.         IFC        '\1','All'
  56.         movem.l        D0-D7/A0-A6,-(SP)
  57.         ENDC
  58.         IFNC        '\1','All'
  59.         movem.l        \1,-(SP)
  60.         ENDC
  61.         ENDM
  62. Pop        MACRO        Pop <reg-list | All>
  63.         IFC        '\1','All'
  64.         movem.l        (SP)+,D0-D7/A0-A6
  65.         ENDC
  66.         IFNC        '\1','All'
  67.         movem.l        (SP)+,\1
  68.         ENDC
  69.         ENDM
  70. rAPtr        MACRO        Name
  71. DefSiz        set        DefSiz+4
  72. DefPtr        set        DefPtr-4
  73. \1        =        DefPtr
  74.         ENDM
  75. rLong        MACRO        Name
  76. DefSiz        set        DefSiz+4
  77. DefPtr        set        DefPtr-4
  78. \1        =        DefPtr
  79.         ENDM
  80. rWord        MACRO        Name
  81. DefSiz        set        DefSiz+2
  82. DefPtr        set        DefPtr-2
  83. \1        =        DefPtr
  84.         ENDM
  85. rByte        MACRO        Name
  86. DefSiz        set        DefSiz+1
  87. DefPtr        set        DefPtr-1
  88. \1        =        DefPtr
  89.         ENDM
  90. rStorage    MACRO        Name,Size    ; Define storage
  91. DefSiz        set        DefSiz+\2
  92. DefPtr        set        DefPtr-\2
  93. \1        =        DefPtr
  94.         ENDM
  95. rEVEN        MACRO                ; Word boundary
  96.         IFNE        DefPtr&1
  97. DefPtr        set        DefPtr-1
  98. DefSiz        set        DefSiz+1
  99.         ENDC
  100.         ENDM
  101. rStart        MACRO                ; Define var section
  102. DefPtr        set        0
  103. DefSiz        set        0
  104.         ENDM
  105. rEnd        MACRO                ; End var section
  106. RelSize        =        DefSiz
  107.         ENDM
  108. rAlloc        MACRO                ; Allocate storage
  109.         link        DB,#-RelSize
  110.         ENDM
  111. rFree        MACRO                ; De-allocate storage
  112.         unlk        DB
  113.         ENDM
  114. rClear        MACRO                ; Reset all variables
  115.         movem.l        D0/A0,-(SP)
  116.         move.w        #RelSize-1,D0
  117.         move.l        DB,A0
  118. rClr.\@        clr.b        -(A0)
  119.         dbf        D0,rClr.\@
  120.         movem.l        (SP)+,D0/A0
  121.         ENDM
  122. Detach        MACRO        ; Detach <'process name'>,stacksize,processpri
  123.         SECTION        SingleSplit,CODE
  124. Start        Prepare        Exec_Call
  125.         suba.l        A1,A1
  126.         CallLib        FindTask        ; Find us
  127.         move.l        D0,A2
  128.         tst.l        pr_CLI(A2)
  129.         bne.S        SegSplit
  130.         jmp        ProcessStart        ; from WorkBench
  131. SegSplit    CallLib        Forbid            ; From Dos
  132.         lea        DName(PC),A1
  133.         CallLib        OldOpenLibrary
  134.         move.l        D0,D5
  135.         beq.S        3$
  136.         moveq        #ML_SIZE+1*ME_SIZE,D0
  137.         move.l        #MEMF_PUBLIC|MEMF_CLEAR,D1
  138.         CallLib        AllocMem        ; Allocate Memlist
  139.         move.l        D0,A2
  140.         tst.l        D0
  141.         beq.S        2$
  142.         move.l        #ProcessName,D1
  143.         moveq        #\3,D2            ; Priority
  144.         move.l        Start-4(PC),D3
  145.         move.l        #\2,D4            ; StackSize
  146.         move.l        D5,A6
  147.         CallLib        CreateProc
  148.         Prepare        Exec_Call
  149.         tst.l        D0
  150.         beq.S        1$
  151.         move.l        D0,A0
  152.         lea        -pr_MsgPort(A0),A0    ; Now we have process
  153.         not.l        pr_CLI(A0)        ; All MY programs will now think they were started from the CLI
  154.         lsl.l        #2,D3
  155.         subq.l        #4,D3
  156.         move.l        D3,A1
  157.         move.w        #1,ML_NUMENTRIES(A2)    ; MemList -> ml_NumEntries    = 1
  158.         move.l        A1,ML_ME+ME_ADDR(A2)    ; MemList -> ml_me[0].me_Addr    = Segment
  159.         move.l        (A1),ML_ME+ME_LENGTH(A2); MemList -> ml_me[0].me_Length    = Length
  160.         lea        TC_MEMENTRY(A0),A0
  161.         move.l        A2,A1
  162.         CallLib        AddTail            ; AddTail(&Process->pr_Task.tc_MemEntry,&MemList->ml_Node);
  163.         lea        Start-4(PC),A0
  164.         clr.l        (A0)            ; Split the segments
  165.         bra.S        2$
  166. 1$        move.l        A2,A1            ; CreateProc failed. Can't do anything then
  167.         moveq        #ML_SIZE+1*ME_SIZE,D0
  168.         CallLib        FreeMem
  169. 2$        move.l        D5,A1
  170.         CallLib        CloseLibrary
  171. 3$        CallLib        Permit
  172.         moveq        #0,D0
  173.         rts
  174. DName        dc.b        'dos.library',0
  175. ProcessName    dc.b        \1,0            ; CreateProc makes a copy of this name
  176.         SECTION        ProcessCode,CODE
  177. ProcessStart
  178.         ENDM
  179.  
  180.         incdir        "AsmInc:"
  181.         include        "exec/exec_lib.i"
  182.         include        "exec/memory.i"
  183.         include        "exec/interrupts.i"
  184.         include        "exec/ports.i"
  185.         include        "intuition/intuition.i"
  186.         include        "intuition/intuitionbase.i"
  187.         include        "intuition/intuition_lib.i"
  188.         include        "graphics/graphics_lib.i"
  189.         include        "libraries/dos_lib.i"
  190.         include        "libraries/dos.i"
  191.         include        "libraries/dosextens.i"
  192.         include        "hardware/intbits.i"
  193.         include        "devices/trackdisk.i"
  194.  
  195. DB        EQUR        A4
  196.  
  197. InitProcess    Detach        <'TD Process'>,4000,0
  198.         rAlloc                    ; Allocate memory for variables
  199.         rClear                    ; Clear the memory
  200.         Prepare        Exec_Call
  201.         lea        Settings1.3H(PC),A0
  202.         cmp.w        #34,LIB_VERSION(A6)
  203.         blt.S        1$
  204.         lea        Settings2.0H(PC),A0
  205. 1$        movem.l        (A0),D0-D4
  206.         movem.l        D0-D4,Version(DB)    ; Initialize variables
  207.         suba.l        A1,A1
  208.         CallLib        FindTask        ; Find us
  209.         move.l        D0,TDProcess(DB)
  210.         move.l        D0,A2
  211.         tst.l        pr_CLI(A2)
  212.         bne.S        GetLibs            ; Also works after segment-splitting
  213. WBenchStartup    lea        pr_MsgPort(A2),A0
  214.         CallLib        WaitPort        ; wait for a message
  215.         lea        pr_MsgPort(A2),A0
  216.         CallLib        GetMsg            ; then get it
  217.         move.l        D0,WBenchMsg(DB)    ; save it for later reply
  218. GetLibs
  219. GetGfx        lea        GfxName(PC),A1
  220.         CallLib        OldOpenLibrary
  221.         move.l        D0,GfxBase(DB)
  222.         beq        Error
  223. GetIntuition    lea        IntName(PC),A1
  224.         CallLib        OldOpenLibrary
  225.         move.l        D0,IntBase(DB)
  226.         beq        Error
  227. GetIOExtTD    moveq        #-1,D0
  228.         CallLib        AllocSignal
  229.         cmpi.b        #-1,D0
  230.         beq        Error
  231.         lea        TDPort(DB),A0
  232.         lea        TDPortName(PC),A1
  233.         move.l        A1,MP+LN_NAME(A0)        ; MsgPort->mp_Node.ln_Name=Name
  234.         clr.b        MP+LN_PRI(A0)            ; MsgPort->mp_Node.ln_Pri =Pri
  235.         move.b        #NT_MSGPORT,MP+LN_TYPE(A0)    ; MsgPort->mp_Node.ln_Type=NT_MSGPORT
  236.         move.b        #PA_SIGNAL,MP_FLAGS(A0)        ; MsgPort->mp_Flags      =PA_SIGNAL
  237.         move.b        D0,MP_SIGBIT(A0)        ; MsgPort->mp_SigBit      =MPSigBit
  238.         lea        TDPort(DB),A1
  239.         move.l        TDProcess(DB),MP_SIGTASK(A1)    ; MsgPort->mp_SigTask     =FindTask(0)
  240.         CallLib        AddPort
  241.         lea        IOExtTD(DB),A1
  242.         move.b        #NT_MESSAGE,IO+MN+LN_TYPE(A1)    ; IOExtTD->io_Message.mn_Node.ln_Type=NT_MESSAGE
  243.         clr.b        IO+MN+LN_PRI(A1)        ; IOExtTD->io_Message.mn_Node.ln_Pri =0
  244.         lea        TDPort(DB),A0
  245.         move.l        A0,IO+MN_REPLYPORT(A1)        ; IOExtTD->io_Message.mn_ReplyPort   =Rep
  246. GetWindow    Prepare        Intuition_Call
  247.         CallLib        OpenWorkBench
  248.         tst.l        D0
  249.         beq        Error
  250.         move.l        D0,A1
  251.         move.w        sc_Width(A1),D0
  252.         sub.w        Width(DB),D0
  253.         lsr.w        #1,D0
  254.         lea        NW(PC),A0
  255.         move.w        D0,nw_LeftEdge(A0)    ; Center the window
  256.         tst.w        Version(DB)
  257.         beq.S        1$
  258.         moveq        #0,D1
  259.         move.b        sc_BarHeight(A1),D1
  260.         move.w        D1,Height(DB)
  261.         subq.w        #7,D1
  262.         lsr.w        #1,D1
  263.         addq.w        #6,D1
  264.         move.w        D1,yPos(DB)
  265. 1$        move.w        Width(DB),nw_Width(A0)
  266.         move.w        Height(DB),nw_Height(A0)
  267.         CallLib        OpenWindow
  268.         move.l        D0,DWindow(DB)
  269.         beq        Error
  270.         move.l        D0,A0
  271.         move.l        wd_RPort(A0),Rp(DB)
  272.         move.l        wd_UserPort(A0),Up(DB)    ; UserPort
  273.         move.l        DWindow(DB),A0
  274.         suba.l        A1,A1
  275.         lea        ScrTitle(PC),A2
  276.         CallLib        SetWindowTitles
  277.         Prepare        Gfx_Call
  278.         move.l        Rp(DB),A2
  279.         move.l        A2,A1
  280.         move.w        AColor(DB),D0
  281.         CallLib        SetAPen
  282.         move.l        A2,A1
  283.         move.w        BColorI(DB),D0
  284.         CallLib        SetBPen
  285.         move.l        A2,A1
  286.         moveq        #RP_JAM2,D0
  287.         CallLib        SetDrMd
  288.         lea        TxtAttr(PC),A0
  289.         CallLib        OpenFont
  290.         move.l        D0,Font(DB)
  291.         beq.S        Error
  292.         move.l        D0,A0
  293.         move.l        A2,A1
  294.         CallLib        SetFont
  295. GetUnits    Prepare        Exec_Call        ; See which drives are available
  296.         lea        Drive3(DB),A2
  297.         moveq        #3,D2
  298. 1$        clr.l        MU_Unit(A2)
  299.         not.w        MU_Number(A2)        ; Was 0, now -1
  300.         move.w        D2,D0
  301.         moveq        #0,D1
  302.         lea        TrackName(PC),A0
  303.         lea        IOExtTD(DB),A1
  304.         CallLib        OpenDevice
  305.         tst.l        D0
  306.         bne.S        2$
  307.         lea        IOExtTD(DB),A1        ; Oh yeah, drive is available
  308.         move.l        IO_UNIT(A1),MU_Unit(A2)    ; Store address of unit-structure
  309.         CallLib        CloseDevice        ; Close Unit again
  310. 2$        addq.l        #MU_SIZE,A2
  311.         dbf        D2,1$
  312. SetInterrupt    lea        TDInterrupt(DB),A1        ; Start vertical-blanking interrupt-server
  313.         move.b        #NT_INTERRUPT,LN_TYPE(A1)    ; TDInterrupt->is_Node.ln_Type=NT_INTERRUPT
  314.         lea        TDIntName(PC),A0
  315.         move.l        A0,LN_NAME(A1)            ; TDInterrupt->is_Node.ln_Name=TDIntName
  316.         lea        TDIntServer(PC),A0
  317.         move.l        A0,IS_CODE(A1)            ; TDInterrupt->is_Code          =TDIntServer
  318.         move.l        DB,IS_DATA(A1)            ; TDInterrupt->is_Data          =DB
  319.         moveq        #INTB_VERTB,D0
  320.         CallLib        AddIntServer
  321.         bra        Main
  322.  
  323. Exit
  324. Error
  325. FreeInterrupt    Prepare        Exec_Call
  326.         lea        TDInterrupt(DB),A1
  327.         tst.l        IS_CODE(A1)        ; If this is set then server has been added
  328.         beq.S        FreeFont
  329.         moveq        #INTB_VERTB,D0
  330.         CallLib        RemIntServer
  331. FreeFont    Prepare        Gfx_Call
  332.         move.l        Font(DB),D0
  333.         beq.S        FreeWindow
  334.         move.l        D0,A1
  335.         CallLib        CloseFont
  336. FreeWindow    Prepare        Intuition_Call
  337.         move.l        DWindow(DB),D0
  338.         beq.S        FreePort
  339.         move.l        D0,A0
  340.         CallLib        CloseWindow
  341. FreePort    Prepare        Exec_Call
  342.         lea        TDPort(DB),A2
  343.         tst.b        MP_SIGBIT(A2)        ; If we have bit we also have port
  344.         beq.S        FreeIntuition
  345.         move.l        A2,A1
  346.         CallLib        RemPort
  347.         moveq        #0,D0
  348.         move.b        MP_SIGBIT(A2),D0
  349.         CallLib        FreeSignal
  350. FreeIntuition    move.l        IntBase(DB),D0
  351.         beq.S        FreeGfx
  352.         move.l        D0,A1
  353.         CallLib        CloseLibrary
  354. FreeGfx        move.l        GfxBase(DB),D0
  355.         beq.S        ReplyWB
  356.         move.l        D0,A1
  357.         CallLib        CloseLibrary
  358. ReplyWB        move.l        WBenchMsg(DB),D2
  359.         beq.S        AllDone
  360.         CallLib        Forbid
  361.         move.l        D2,A1
  362.         CallLib        ReplyMsg        ; Reply WBenchMessage if we are started from WB
  363. AllDone        rFree
  364.         moveq        #0,D0
  365.         rts
  366.  
  367. Main
  368. Change        Call        UpdateDisplay
  369. EventLoop    move.l        Up(DB),A0
  370.         moveq        #0,D0
  371.         moveq        #0,D1
  372.         move.b        MP_SIGBIT(A0),D1
  373.         bset        D1,D0
  374.         bset        #SIGBREAKB_CTRL_D,D0
  375.         Prepare        Exec_Call
  376.         CallLib        Wait
  377.         btst        #SIGBREAKB_CTRL_D,D0
  378.         beq.S        GetNextMsg
  379.         lea        TDDrives+29(PC),A1
  380.         lea        Drive3(DB),A0
  381.         moveq        #'0',D2
  382.         moveq        #3,D1
  383. 1$        move.w        MU_Number(A0),D0
  384.         bmi.S        2$
  385.         ext.l        D0
  386.         divu        #10,D0
  387.         add.w        D2,D0
  388.         move.b        D0,(A1)
  389.         swap        D0
  390.         add.w        D2,D0
  391.         move.b        D0,1(A1)
  392. 2$        subq.l        #8,A1
  393.         addq.l        #MU_SIZE,A0
  394.         dbf        D1,1$
  395.         bra.S        Change
  396.  
  397. GetNextMsg    move.l        Up(DB),A0
  398.         Prepare        Exec_Call
  399.         CallLib        GetMsg
  400.         tst.l        D0
  401.         beq.S        EventLoop
  402.         move.l        D0,A1
  403.         move.l        im_Class(A1),D2
  404.         CallLib        ReplyMsg
  405.         cmp.l        #CLOSEWINDOW,D2
  406.         beq        Exit
  407.         tst.w        Version(DB)        ; No need to change color
  408.         beq.S        3$            ; under 1.2/1.3
  409.         cmp.l        #ACTIVEWINDOW,D2
  410.         bne.S        1$
  411.         move.w        BColorA(DB),D0
  412.         bra.S        2$
  413. 1$        cmp.l        #INACTIVEWINDOW,D2
  414.         bne.S        3$
  415.         move.w        BColorI(DB),D0
  416. 2$        move.l        Rp(DB),A1
  417.         Prepare        Gfx_Call
  418.         CallLib        SetBPen
  419. 3$        Call        UpdateDisplay        ; Do some refreshing
  420.         bra.S        GetNextMsg
  421.  
  422. UpdateDisplay    Prepare        Gfx_Call
  423.         move.l        Rp(DB),A1
  424.         move.w        xPos(DB),D0
  425.         move.w        yPos(DB),D1
  426.         CallLib        Move
  427.         lea        TDDrives(PC),A0
  428.         move.l        Rp(DB),A1
  429.         moveq        #StringLength,D0
  430.         CallLib        Text
  431.         rts
  432.  
  433. * A1=DB
  434. * Inside the server the registers D0-D1/A0-A1/A5-A6 can be used
  435. * without restoring them on exit
  436. TDIntServer    Push        D2/DB
  437.         move.l        A1,DB
  438.         moveq        #0,D2            ; Don't signal
  439.         lea        Drive3(DB),A0
  440.         moveq        #3,D1
  441. 1$        move.l        MU_Unit(A0),D0
  442.         beq.S        2$            ; Does drive exist
  443.         move.l        D0,A1
  444.         add.w        UOffset(DB),A1
  445.         move.w        (A1),D0
  446.         asr.w        #1,D0
  447.         cmp.w        MU_Number(A0),D0
  448.         beq.S        2$
  449.         move.w        D0,MU_Number(A0)
  450.         moveq        #1,D2            ; Do signal
  451. 2$        addq.l        #MU_SIZE,A0
  452.         dbf        D1,1$
  453.         tst.w        D2
  454.         beq.S        3$
  455.         move.l        TDProcess(DB),A1
  456.         move.l        #SIGBREAKF_CTRL_D,D0
  457.         Prepare        Exec_Call
  458.         CallLib        Signal
  459. 3$        Pop        D2/DB
  460.         rts
  461.  
  462. * My Unit structure
  463. MU_Unit        =0            ; Address of drive-unit
  464. MU_Number    =4            ; Track number
  465. MU_SIZE        =6
  466.  
  467. * Stack variables
  468.  rStart
  469.  rAPtr        TDProcess        ; This process 
  470.  rAPtr        GfxBase
  471.  rAPtr        IntBase
  472.  rAPtr        WBenchMsg        ; Message from Workbench
  473.  rAPtr        DWindow            ; APtr to Window
  474.  rAPtr        Rp            ; APtr to RastPort
  475.  rAPtr        Up            ; APtr to UserPort
  476.  rAPtr        Font            ; APtr to Topaz-80
  477.  rStorage    IOExtTD,IOTD_SIZE    ; IOExtTD structure
  478.  rStorage    TDPort,MP_SIZE        ; MessagePort structure
  479.  rStorage    TDInterrupt,IS_SIZE    ; Interrupt structure
  480.  rStorage    Drive0,MU_SIZE
  481.  rStorage    Drive1,MU_SIZE
  482.  rStorage    Drive2,MU_SIZE
  483.  rStorage    Drive3,MU_SIZE
  484.  rWord        WordPad            ; DON'T REMOVE (Setting are now 10 words)
  485.  rWord        BColorI            ; Background color (Inactive)
  486.  rWord        BColorA            ; Background color (Active)
  487.  rWord        AColor            ; Foreground color
  488.  rWord        yPos            ; y-position of text in window
  489.  rWord        xPos            ; x-position of text in window
  490.  rWord        Height            ; Height of window
  491.  rWord        Width            ; Width of window
  492.  rWord        UOffset            ; Offset into unit structure (to get to track indicator)
  493.  rWord        Version            ; Kickstart version ID
  494.  rEnd
  495.  
  496. GfxName        dc.b        'graphics.library',0
  497. IntName        dc.b        'intuition.library',0
  498. TrackName    dc.b        'trackdisk.device',0
  499. TDIntName    dc.b        'TD Interrupt',0
  500. TDPortName    dc.b        'TD Port',0
  501. TDDrives    dc.b        'DF0: -- DF1: -- DF2: -- DF3: --',0
  502. ScrTitle    dc.b        'TD V1.0 1991 by Preben Nielsen. Thanks Olaf Barthel',0
  503.         EVEN
  504.  
  505. StringLength    =31
  506. StringSpace    =StringLength*8
  507.  
  508. Kick1        =0
  509. * Defines for hires under kickstart 1.2-1.3 (and below ?)
  510. Offset1.3    =74
  511. Width1.3H    =1+84+StringSpace
  512. Height1.3H    =10
  513. xPos1.3H    =30
  514. yPos1.3H    =7
  515. AColor1.3H    =0
  516. BColor1.3H    =1
  517.  
  518. Kick2        =1
  519. * Defines for hires under kickstart 2.0 (and up ?)
  520. Offset2.0    =54
  521. Width2.0H    =51+StringSpace
  522. Height2.0H    =11
  523. xPos2.0H    =23
  524. yPos2.0H    =8
  525. AColor2.0H    =1
  526. BColor2.0HA    =3        ; Active background color
  527. BColor2.0HI    =0        ; Inactive background color
  528.  
  529. Settings1.3H    dc.w        Kick1,Offset1.3,Width1.3H,Height1.3H,xPos1.3H,yPos1.3H,AColor1.3H,BColor1.3H,BColor1.3H,0
  530. Settings2.0H    dc.w        Kick2,Offset2.0,Width2.0H,Height2.0H,xPos2.0H,yPos2.0H,AColor2.0H,BColor2.0HA,BColor2.0HI,0
  531.  
  532. IDCMP_Flags    =        CLOSEWINDOW|INACTIVEWINDOW|ACTIVEWINDOW
  533. Other_Flags    =        RMBTRAP|WINDOWCLOSE|WINDOWDEPTH|WINDOWDRAG
  534. NW        dc.w        0,0,0,0
  535.         dc.b        0,1
  536.         dc.l        IDCMP_Flags,Other_Flags
  537.         dc.l        0,0,0,0,0
  538.         dc.w        0,0,0,0,WBENCHSCREEN
  539.  
  540. TxtAttr        dc.l        FontName
  541.         dc.w        TOPAZ_EIGHTY
  542.         dc.b        FS_NORMAL,FPB_ROMFONT
  543. FontName    dc.b        'topaz.font',0
  544.         END
  545.  
  546.